Windows 11'i Güvenli Kip'te başlatmak için ".bat" dosyası

3613 · 8 Eylül 2025

Yalnizca PIN ile sistemi aciyorsaniz kullanmayin, yönetici haklari olan Yerel hesap gereklidir.

Windows 11'i güvenli kipte açmak oldukça yorucu. Örneğin DDU gibi bir aracı çalıştırmak istediğinizde uğraştırıcı oluyor. Bunu sadeleştirmek için bir bat dosyası oluşturdum.

Yönetici hakları ile çalıştırmanız gerekli. Önce hangi modun çalıştığını kontrol ediyor. Normal modda ise yeniden başlatıyor ve güvenli kipte açılıyor Windows. DDU ile işiniz bittiğinde bu işlemi bir daha yapmanız lazım. Direkt restart ederseniz yine güvenli kipte açılır yoksa.

Kod:

@echo off
:: ---------------------------
:: Yönetici yetkisi kontrolü
:: ---------------------------
>nul 2>&1 icacls "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
    echo Yönetici izni gerekiyor...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
echo Set UAC = CreateObject("Shell.Application") > "%temp%\getadmin.vbs"
set params=%*:\"=\"\"
echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"
exit /B

:gotAdmin
CD /D "%~dp0"

:: ---------------------------
:: Güvenli kip kontrol ve geçiş
:: ---------------------------
bcdedit | find "safeboot" >nul
if %errorlevel%==0 (
    echo Guvenli moddayiz, normal moda geciliyor...
    bcdedit /deletevalue {current} safeboot
    shutdown /r /t 0
) else (
    echo Normal moddayiz, guvenli moda geciliyor...
    bcdedit /set {current} safeboot minimal
    shutdown /r /t 0
)

AceTeq · 8 Eylül 2025

Aslında ben de böyle bir araç yapacaktım ama güvenli moda geçmek için gerek olmadığı kanatine var mıştım. VBS oluşturmaya gerek yok yönetici çalıştırmak için. PowerShell komutu kullanmak daha kolay bence. Ayrıca Windows 11'in Bug'a girmesine sebep olabilir, dikkatli kullanılması gerekiyor. Ethernet'i olmayan kullancılar bu aracı kullandığında sistem internetten kopar ve MS hesabı açıksa sisteme ulaşmak aşırı zor hale gelir. Betiği daha da geliştirmen lazım.

3613 · 8 Eylül 2025

AceTeq dedi:
.vbs oluşturmaya gerek yok yönetici çalıştırmak için. PowerShell komutu kullanmak daha kolay bence. Ayrıca Windows 11'in bug'a girmesine sebep olabilir, dikkatli kullanılması gerekiyor. Ethernet'i olmayan kullancılar bu aracı kullandığında sistem internetten kopar ve MS hesabı açıksa sisteme ulaşmak aşırı zor hale gelir. Betiği daha da geliştirmen lazım.

Bu .vbs degil. cmd'den calisan batch kutugu. .ps1 yani powershell scripti olusturunca yonetici haklari ile calistirmak sorun oluyor. bat dosyasinda ise sag tus yonetici haklari ile calistir demek yeterli. Bug a girmesi icin bir neden yok, yaptigi islem zaten Windows'un kendi menusunden guvenli kipte baslat komutunun aynisi. Internetten kopacak zaten, guvenli kipe giriyorsun. Gelistirmek icin fikrini bekliyorum. Ne gibi bir islem yapmasini istiyorsun? Ne eklenebilir?

AceTeq · 8 Eylül 2025

3613 dedi:
Bu .vbs degil. cmd'den calisan batch kutugu. .ps1 yani powershell scripti olusturunca yonetici haklari ile calistirmak sorun oluyor. bat dosyasinda ise sag tus yonetici haklari ile calistir demek yeterli. Bug a girmesi icin bir neden yok, yaptigi islem zaten Windows'un kendi menusunden guvenli kipte baslat komutunun aynisi. Internetten kopacak zaten, guvenli kipe giriyorsun. Gelistirmek icin fikrini bekliyorum. Ne gibi bir islem yapmasini istiyorsun? Ne eklenebilir?

Demek istediğim, sistemde MS hesabı açıksa ve PIN kullanılıyorsa, PIN güvenli modda kullanılamaz hale gelir. Güvenli modda internet olmayacağından PIN'i sıfırlayamazsınız ve sisteme erişimi kaybedersiniz. Erişmek için daha farklı yöntemlerle uğraşmanız gerekir.

Otomatik yönetici yükseltmesi için betiğin başına şunu ekleyebilirsiniz:

Kod:

net session >nul 2>&1
if %errorlevel% neq 0 (
    echo(
    echo ----------------------------------------------
    echo      Yonetici olarak tekrar baslatiliyor...
    echo ----------------------------------------------
    timeout /t 2 >nul
    powershell -windowstyle hidden -command "Start-Process '%~f0' -Verb runAs"
    exit /b
)

PIN olayına gelirsek, bunu daha düzgün bir şekilde halletmek için çok daha karmaşık bir betik gerekiyor. Ben sırf güvenli mod için bu kadar zahmet etmeye gerek duymadım. En azında PIN kullananlar için bir uyarı eklemelisin.

26225 · 8 Eylül 2025

Windows 11'i güvenli kipte açmak oldukça yorucu.

Yorucu falan değil. Msconfig ile 5 saniyelik iş.

3613 · 8 Eylül 2025

AceTeq dedi:
Demek istediğim, sistemde MS hesabı açıksa ve PIN kullanılıyorsa, PIN güvenli modda kullanılamaz hale gelir. Güvenli modda internet olmayacağından PIN'i sıfırlayamazsınız ve sisteme erişimi kaybedersiniz. Erişmek için daha farklı yöntemlerle uğraşmanız gerekir.

Otomatik yönetici yükseltmesi için betiğin başına şunu ekleyebilirsiniz:

Kod:

net session >nul 2>&1 if %errorlevel% neq 0 ( echo( echo ---------------------------------------------- echo Yonetici olarak tekrar baslatiliyor... echo ---------------------------------------------- timeout /t 2 >nul powershell -windowstyle hidden -command "Start-Process '%~f0' -Verb runAs" exit /b )

PIN olayına gelirsek, bunu daha düzgün bir şekilde halletmek için çok daha karmaşık bir betik gerekiyor. Ben sırf güvenli mod için bu kadar zahmet etmeye gerek duymadım. En azında PIN kullananlar için bir uyarı eklemelisin.

Bahsettigin sorun salt bu dosya ile degil klasik yontemle guvenli kipte actiginda da ortaya cikiyor yalniz. Bunu asmak icin MS'nin dokumantasyonunda bir yontem goremedim. Yonetici haklari ile yerel hesap acmak lazim bildigim kadariyla. Oyle yapip guvenli kipte yerel hesap sifresiyle acilablir. Acikcasi ugrasmak icin gerekte gormedim. Nasil olsa baska sekilde de guvenli kipe girse ayni durumla karsilasilacak. Bu yuzden sifresini bilmeyen zaten giremez. O da onun problemi.

Yine de not dusmek gerekli tabii, sifresini bilmeyen kullanmasin.

26225 dedi:
Yorucu falan değil. Msconfig ile 5 saniyelik iş.

Eki Görüntüle 183198

Evet, dogru soyluyorsun. 5 saniye icinde yapabiliyorsun. Bu sekilde ise 0.5 saniye.

Windows 11'i Güvenli Kip'te başlatmak için ".bat" dosyası

Detaylar

3613

Üstün

AceTeq

Üstün

3613

Üstün

AceTeq

Üstün

26225

Becerikli

3613

Üstün

Benzer konular

Yeni konular

Yeni mesajlar