Çözüm Yönetici olarak otomatik .msi dosyası çalıştırma

@echo off
chcp 65001 >nul
color f
setlocal
title msi. Kurulum Aracı v1.1

net session >nul 2>&1
if %errorlevel% neq 0 (
    echo(
    echo ──────────────────────────────────────────────
    echo     Yönetici olarak tekrar başlatılıyor...
    echo ──────────────────────────────────────────────
    timeout /t 2 >nul
    powershell -windowstyle hidden -command "Start-Process '%~f0' -Verb runAs"
    exit /b
)

cd /d "%~dp0"

set "msiCount=0"
for %%F in (*.msi) do (
    set /a msiCount+=1
    set "msiFile=%%F"
)

if %msiCount%==0 (
    echo ─────────────────────────────────────────────────────────────────────
    echo   Bu klasörde hiçbir .msi dosyası bulunamadı. İşlem iptal edildi...   
    echo ─────────────────────────────────────────────────────────────────────
    timeout /t 3 >nul
    exit /b
)

if %msiCount% gtr 1 (
    echo ────────────────────────────────────────────────────────────────────
    echo   Lütfen sadece ilgili dosyayı bırakınız... İşlem iptal edildi...
    echo ────────────────────────────────────────────────────────────────────
    timeout /t 3 >nul
    exit /b
)

echo ───────────────────────────────────────────────────────────────────────
echo   Kurulmak üzere hazır durumda.
echo   "%msiFile%"
echo ───────────────────────────────────────────────────────────────────────
set /p userChoice="Devam etmek istiyor musunuz? (E/H): "
if /i not "%userChoice%"=="E" (
    echo Kurulum kullanıcı tarafından iptal edildi.
    timeout /t 3 >nul
    exit /b
)

echo ─────────────────────────────────
echo   Kurulum başlatıldı...
echo ─────────────────────────────────
msiexec /i "%msiFile%"