Rehber Windows’ta “Kuruluşunuz Tarafından Yönetiliyor” uyarısını kaldırma

@echo off
title Windows Politika Temizleyici v2.1
color f
setlocal EnableDelayedExpansion

net session >nul 2>&1
if %errorlevel% neq 0 (
    echo(
    echo --------------------------------------------
    echo    Yonetici olarak tekrar baslatiliyor...
    echo --------------------------------------------
    timeout /t 2 >nul
    powershell -windowstyle hidden -command "Start-Process '%~f0' -Verb runAs"
    exit /b
)

echo --------------------------------------------------
echo    Bu islem sistem politikalarini sifirlayacak.
echo --------------------------------------------------
choice /c EH /n /m "   Devam etmek istiyor musunuz? [E/H]: "
if errorlevel 2 (
    echo ----------------------------------------------
    echo    Islem kullanici tarafindan iptal edildi.
    echo ----------------------------------------------
    timeout /t 3 >nul
    exit /b
)

echo Yedekleme baslatildi...
timeout /t 1 /nobreak >nul
set "backup_dir=%SystemDrive%\PolitikaYedekleri"
mkdir "%backup_dir%" >nul 2>&1

for /f %%i in ('powershell -NoProfile -Command "Get-Date -Format \"yyyy-MM-dd--HH-mm\""') do set timestamp=%%i

reg export "HKLM\SOFTWARE\Policies" "%backup_dir%\HKLM_Policies_%timestamp%.reg" /y >nul
reg export "HKCU\SOFTWARE\Policies" "%backup_dir%\HKCU_Policies_%timestamp%.reg" /y >nul
reg export "HKLM\SOFTWARE\Microsoft\PolicyManager" "%backup_dir%\HKLM_PolicyManager_%timestamp%.reg" /y 2>nul
reg export "HKCU\SOFTWARE\Microsoft\PolicyManager" "%backup_dir%\HKCU_PolicyManager_%timestamp%.reg" /y 2>nul

echo Belirtilen dizine kaydedildi: %backup_dir%
timeout /t 1 /nobreak >nul

echo -----------------------------------------------------------------------
echo    Sistem beklenmedik sekilde davranirsa, yedekleri geri yukleyiniz.
echo -----------------------------------------------------------------------

echo Politika temizligi baslatildi...
timeout /t 1 /nobreak >nul

reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies" /f >nul 2>&1
reg delete "HKCU\Software\Microsoft\WindowsSelfHost" /f >nul 2>&1
reg delete "HKCU\Software\Policies\Microsoft\Windows\System" /f >nul 2>&1
reg delete "HKCU\Software\Policies\Microsoft\Windows\Explorer" /f >nul 2>&1
reg delete "HKCU\Software\Policies\Microsoft\Windows\CurrentVersion\PushNotifications" /f >nul 2>&1

reg delete "HKLM\Software\Microsoft\Policies" /f >nul 2>&1
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\Policies" /f >nul 2>&1
reg delete "HKLM\Software\Microsoft\WindowsSelfHost" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\System" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /f >nul 2>&1

reg delete "HKLM\SOFTWARE\Microsoft\Enrollments" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\Provisioning" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\PushToInstall" /f >nul 2>&1

reg delete "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\Education" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\DataCollection" /f >nul 2>&1
reg delete "HKLM\SOFTWARE\Microsoft\PolicyManager\current\device\CloudContent" /f >nul 2>&1

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v EnableLUA /t REG_DWORD /d 1 /f >nul
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v ConsentPromptBehaviorAdmin /t REG_DWORD /d 5 /f >nul
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System" /v PromptOnSecureDesktop /t REG_DWORD /d 1 /f >nul

echo Grup ilkesi yeniden yapilandiriliyor...
gpupdate /force >nul

echo Kabuk bilesenleri yeniden baslatiliyor...
taskkill /f /im explorer.exe >nul 2>&1
taskkill /f /im ShellExperienceHost.exe >nul 2>&1
taskkill /f /im StartMenuExperienceHost.exe >nul 2>&1
start "" explorer.exe
timeout /t 1 >nul

echo ----------------------------------------------------------------
echo    Temizlik tamamlandi. Sistemi yeniden baslatmaniz onerilir.
echo                 Cikmak icin bir tusa basin...
echo ----------------------------------------------------------------
pause >nul