Rehber Windows Update geçmişi temizleme rehberi

@echo off
chcp 65001 >nul
setlocal EnableDelayedExpansion
color f
title Windows Update Temizleyici v2.3

net session >nul 2>&1
if %errorlevel% neq 0 (
    echo(
    echo ──────────────────────────────────────────────
    echo     Yönetici olarak tekrar başlatılıyor...
    echo ──────────────────────────────────────────────
    timeout /t 2 >nul
    powershell -windowstyle hidden -command "Start-Process '%~f0' -Verb runAs"
    exit /b
)

echo ──────────────────────────────────────────────────────────────────────────────────────────
echo   Windows Update hizmetleri durdurulacak, geçici dosyalar, loglar ve cache temizlenecek.
echo ──────────────────────────────────────────────────────────────────────────────────────────
choice /c EH /n /m "   Devam etmek istiyor musunuz? [E/H]: "
set "choiceError=%errorlevel%"

if %choiceError%==2 (
    echo ──────────────────────────────────────────────
    echo    İşlem kullanıcı tarafından iptal edildi.
    echo ──────────────────────────────────────────────
    timeout /t 3 >nul
    exit /b
)

echo [1/9] Windows Update hizmetleri durduruluyor...
call :StopService usosvc
call :StopService wuauserv
call :StopService bits
call :StopService cryptsvc
timeout /t 1 >nul

echo [2/9] Güncelleme önbellek klasörleri temizleniyor...
attrib -h -r -s "%SystemRoot%\SoftwareDistribution\Download" >nul 2>&1
rd /s /q "%SystemRoot%\SoftwareDistribution\Download" >nul 2>&1
rd /s /q "%SystemRoot%\SoftwareDistribution\DataStore" >nul 2>&1
rd /s /q "%SystemRoot%\SoftwareDistribution\EventCache.v2" >nul 2>&1
del /f /q "%SystemRoot%\SoftwareDistribution\ReportingEvents.log" >nul 2>&1

attrib -h -r -s "%SystemRoot%\System32\catroot2" >nul 2>&1
del /f /s /q "%SystemRoot%\System32\catroot2\*" >nul 2>&1
timeout /t 1 >nul

echo [3/9] Teslim İyileştirme ve USO önbelleği temizleniyor...
del /f /q "%ProgramData%\USOPrivate\UpdateStore\*" >nul 2>&1

attrib -h -r -s "%ProgramData%\Microsoft\Network\Downloader" >nul 2>&1
rd /s /q "%ProgramData%\Microsoft\Network\Downloader" >nul 2>&1
del /f /q "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr*.dat" >nul 2>&1

attrib -h -r -s "%SystemRoot%\SoftwareDistribution\DeliveryOptimization" >nul 2>&1
rd /s /q "%SystemRoot%\SoftwareDistribution\DeliveryOptimization" >nul 2>&1
timeout /t 1 >nul

echo [4/9] Güncelleme logları ve sistem geçici klasörleri temizleniyor...
del /f /q "%SystemRoot%\WindowsUpdate.log" >nul 2>&1
rd /s /q "%SystemRoot%\Logs\CBS" >nul 2>&1
rd /s /q "%SystemRoot%\Logs\DISM" >nul 2>&1
rd /s /q "%SystemRoot%\Logs\MoSetup" >nul 2>&1
timeout /t 1 >nul

echo [5/9] WinSxS geçici klasörleri ve ManifestCache temizleniyor...
del /f /s /q "%SystemRoot%\WinSxS\Temp\PendingDeletes\*" >nul 2>&1
del /f /s /q "%SystemRoot%\WinSxS\Temp\PendingRenames\*" >nul 2>&1

attrib -h -r -s "%SystemRoot%\WinSxS\ManifestCache" >nul 2>&1
del /f /s /q "%SystemRoot%\WinSxS\ManifestCache\*" >nul 2>&1
timeout /t 1 >nul

echo [6/9] Windows Update kimlik kayıtları temizleniyor...
reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate" /v SusClientId >nul 2>&1
if %errorlevel%==0 (
    reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate" /v SusClientId /f >nul
    echo   - SusClientId girdisi temizlendi.
) else (
    echo   - SusClientId girdisi bulunamadı.
)

reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate" /v SusClientIdValidation >nul 2>&1
if %errorlevel%==0 (
    reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate" /v SusClientIdValidation /f >nul
    echo   - SusClientIdValidation girdisi temizlendi.
) else (
    echo   - SusClientIdValidation girdisi bulunamadı.
)
timeout /t 1 >nul

echo [7/9] Eski bileşenler ve kurulum klasörleri kaldırılıyor...
dism /online /cleanup-image /startcomponentcleanup /resetbase >nul 2>&1

attrib -h -r -s "C:\$WINDOWS.~BT" >nul 2>&1
rd /s /q "C:\$WINDOWS.~BT" >nul 2>&1
if exist "C:\$WINDOWS.~BT" (
    echo   - $WINDOWS.~BT klasörü kaldırılamadı ya da korumalı olabilir.
) else (
    echo   - $WINDOWS.~BT klasörü kaldırıldı.
)

attrib -h -r -s "C:\$WINDOWS.~WS" >nul 2>&1
rd /s /q "C:\$WINDOWS.~WS" >nul 2>&1
if exist "C:\$WINDOWS.~WS" (
    echo   - $WINDOWS.~WS klasörü kaldırılamadı ya da korumalı olabilir.
) else (
    echo   - $WINDOWS.~WS klasörü kaldırıldı.
)
timeout /t 1 >nul

echo [8/9] Windows Update hizmetleri yeniden başlatılıyor...
call :StartIfStopped cryptsvc
call :StartIfStopped bits
call :StartIfStopped wuauserv
call :StartIfStopped usosvc
timeout /t 1 >nul

echo [9/9] Windows Update istemcisi yeniden tetikleniyor...
UsoClient.exe RefreshSettings >nul 2>&1
UsoClient.exe StartScan >nul 2>&1
timeout /t 1 >nul

echo ──────────────────────────────────────────────────────────────────────────────────────────────
echo    İşlemler tamamlandı. Sistemi yeniden başlatmanız önerilir. Çıkmak için bir tuşa basın...
echo ──────────────────────────────────────────────────────────────────────────────────────────────
pause >nul
endlocal
exit /b

:StopService
sc query %1 | findstr /i "STATE" | findstr /i "STOPPED" >nul
if !errorlevel! equ 0 (
    echo   - %1 zaten pasif durumda.
) else (
    echo   - %1 durduruluyor...
    sc stop %1 >nul
)
goto :eof

:StartIfStopped
sc query %1 | findstr /i "STATE" | findstr /i "STOPPED" >nul
if !errorlevel! equ 0 (
    net start %1 >nul
)
goto :eof