Dosyaların adını random yapan program önerisi

[.ShellClassInfo]
LocalizedResourceName=@%SystemRoot%\system32\shell32.dll,-21798
IconResource=%SystemRoot%\system32\imageres.dll,-184

@echo off
title Rastgele isimlendirici - by Hasan Merkit
setlocal enabledelayedexpansion

REM Buradan klasör yolunu değiştirebilirsiniz.
REM Ancak, set='den sonra girin ve sondaki tırnağı silmeyin. Böylece boşlukda destekleyeceğiz.

set "Klasor_Yolu=%USERPROFILE%\Downloads"

REM Bu script, Hasan Merkit tarafından yazılmıştır.
REM Bu script, her zaman kusuruz çalışmayabilir. Hiçbir garantisi yoktur.
REM Bu script, kullanana kişi sorumluluğundadır.
REM Kodları okuyabilirsiniz.

REM Belirlenen klasör gerçekten var mı? Kontrol edelim. Yoksa kullanıcıyı tebrik edelim.
if not exist "%Klasor_Yolu%" (
    echo [^^!] Belirlenen yolda klasor bulunamadi.
    echo     Cikmak icin bir tusa bas. & pause>nul & exit /b 1
)

REM Bazen bir hata sonucu %Klasör_Yolu% değişken içeriği boş gelebilir.
if "%Klasor_Yolu%" == "" (
    echo [^^!] Klasor belirtmediniz veya klasor adi alinamadi.
    echo     Cikmak icin bir tusa bas. & pause>nul & exit /b 1
)

REM Burada FOR döngüsü oluşturarak bir işlemi klasörün altındaki tüm dosyalar için tekrarlayacağım.
for %%A in (%Klasor_Yolu%\*) do (

    REM "Thumbs.db" ve "desktop.ini" dosyalarını atlıyoruz
    if /I "%%~nxA" neq "Thumbs.db" if /I "%%~nxA" neq "desktop.ini" (

        REM Şimdi burada random 10 karakterlik rastgele harfler oluşturuyor, %Rastgele% değişkenine atıyorum.
        set "Rastgele="
        for /L %%i in (1,1,10) do (
            set /A "rand=!random! %% 26"
            for %%j in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
                set /A "index+=1"
                if !index! equ !rand! set "letter=%%j"
            )
            set "Rastgele=!Rastgele!!letter!"
            set index=0
        )

        REM Dosya uzantısını alıyoruz
        for %%B in ("%%A") do set "ext=%%~xB"

        REM Şimdi burada dosyaya %RASTGELE% ismi verelim.
        echo [i] Yeniden isimlendiriliyor: %%A , yeni adi !Rastgele!!ext!
      
        REM Dosyayı yeniden adlandırıyoruz
        ren "%%A" "!Rastgele!!ext!"
    )
)

echo [i] Script sonu.
echo     Devam etmek icin bir tusa basin. & pause>nul